= threshold) [TRUE] [FALSE] ]
[ if not protect? and (decision-value >= threshold) [ set protect? TRUE ] ]
]
end
to spread-epidemic
ask patches [ set incidence 0 ]
ask patches
[ ; calculate the number of new infections generated by the patch
let beta (R0 / recovery-period) * (1 - efficacy * (count people-here with [protect?] / count people-here))
let new-cases popn-I * beta * popn-S / popn
ask one-of neighbors [ set incidence incidence + travel-rate * [new-cases] of myself ]
set incidence incidence + (1 - travel-rate) * new-cases
]
ask patches
[ ; update the population counts in each epidemic state
let recovered popn-I / recovery-period
if incidence > popn-S [ set incidence popn-S ]
set popn-S popn-S - incidence
set popn-I popn-I - recovered + incidence
if popn-I < 1 [ set popn-I 0 ]
set popn-R round (popn-R + recovered)
update-threat
]
end
to epidemic-people
; infected to recovered
let infecteds people with [state = "I"]
if any? infecteds
[ ask infecteds
[ if random-float 1 < (1 / recovery-period) [ set state "R" ]
]
]
; susceptible to infected
let susceptibles people with [state = "S"]
if any? susceptibles
[ ask susceptibles
[ let protect-here count people-here with [protect?] / count people-here
let infect-here incidence / (incidence + popn-S)
ifelse all? people-here [protect?]
[ if random-float 1 < infect-here [ set state "I" ] ]
[ let prob ifelse-value protect?
[ infect-here * (1 - efficacy) / (1 - protect-here * efficacy) ]
[ infect-here / (1 - protect-here * efficacy) ]
if random-float 1 < prob [ set state "I" ]
]
]
]
end
to colour-barriers
ask barriers
[ if-else count people-here with [protect?] / count people-here >= show-protect
[show-turtle]
[hide-turtle]
]
end
to setup-patches
ask patches [ set popn 2000 + random 10000 ]
ask n-of 3 patches [ set popn 1000000 * (3 + random 3) ]
repeat 3 [ diffuse popn 0.4 ]
ask patches
[ set popn round popn
set incidence 0
set popn-S popn
set popn-I 0
set popn-R 0
set visible patches in-radius see-distance
]
set max-popn max [popn] of patches
end
to update-threat ; patch procedure
set threat incidence / popn + (1 - threat-discount) * threat
end
to make-people
ask patches
[ sprout-people (2 + floor ( popn / 10000 ))
[ set protect? FALSE
set size 0
set attitude triangular0to1 0.8
set state "S"
]
]
end
to make-barriers
ask patches
[ sprout-barriers 1
[ set shape "x"
set size 0.7
set color black
hide-turtle
]
]
end
to make-network
let lonely people
ask people
[ set lonely other lonely
let needed round num-friends - count my-links
if needed > 0
[ let targets n-of min (list needed count lonely) lonely
create-links-with targets [ hide-link]
ask targets [ if count my-links = num-friends [ set lonely other lonely ] ]
]
]
end
to make-network-original
ask people
[ let needed num-friends - count my-links
if needed > 0
[ let candidates other people with [ count my-links < num-friends]
create-links-with n-of min (list needed count candidates) candidates
[ hide-link]
]
]
end
to start-epidemic
ask n-of 3 max-n-of 20 patches [ popn ]
[ set popn-I round (0.005 * popn)
set popn-S popn-S - popn-I
]
end
to update-globals
let protected count people with [protect?] / count people
if protected > max-protect
[ set max-protect protected
set when-max-protect ticks
]
end
;--------------------------------------------------
; UTILITY PROCEDURES
;--------------------------------------------------
to colour-patches
let max-scale 1.3 * ln max-popn
ask patches
[ ifelse popn-S > popn-R
[ set pcolor scale-color blue ln popn max-scale 3.2 ]
[ set pcolor scale-color green ln popn max-scale 1.5 ]
if popn-I >= 1
[ set pcolor ifelse-value (popn-I > 0.03 * popn) [16] [18] ]
]
end
to-report triangular0to1 [ #Mode ]
report random-triangular #Mode 0 1
end
to-report random-triangular [ #Mode #Lower #Upper ]
let uRand random-float 1
let scale (#Mode - #Lower) / (#Upper - #Lower)
report ifelse-value (uRand < scale)
[ #Lower + sqrt(uRand * (#Upper - #Lower) * (#Mode - #Lower)) ]
[ #Upper - sqrt((1 - uRand) * (#Upper - #Lower) * (#Upper - #Mode))]
end
to-report all-done?
report ifelse-value (sum [popn-I] of patches > 0) [FALSE] [TRUE]
end]]>count people with [state = "I" and protect?] / count people with [protect?](sum [popn-I] of patches + sum [popn-R] of patches) / sum [popn] of patchescount people with [state = "I" and not protect?] / count people with [not protect?]when-max-protectmax-protectplot sum [incidence] of patches / sum [popn] of patchesplot sum [popn-I] of patches / sum [popn] of patchesplot count people with [protect?] / count peopleEpidemic ParametersBehaviour Decisions## WHAT IS IT?
(a general understanding of what the model is trying to show or explain)
## HOW IT WORKS
(what rules the agents use to create the overall behavior of the model)
## HOW TO USE IT
(how to use the model, including a description of each of the items in the Interface tab)
## THINGS TO NOTICE
(suggested things for the user to notice while running the model)
## THINGS TO TRY
(suggested things for the user to try to do (move sliders, switches, etc.) with the model)
## EXTENDING THE MODEL
(suggested things to add or change in the Code tab to make the model more complicated, detailed, accurate, etc.)
## NETLOGO FEATURES
(interesting or unusual features of NetLogo that the model uses, particularly in the Code tab; or where workarounds were needed for missing features)
## RELATED MODELS
(models in the NetLogo Models Library and elsewhere which are of related interest)
## CREDITS AND REFERENCES
(a reference to the model's URL on the web if it has one, as well as any other necessary credits, citations, and links)setup repeat 75 [ go ]